b4d/cfdg
1
0
Fork 0
Code Issues Pull Requests Releases Wiki Activity

Init 2

Browse Source
This commit is contained in:
Deni 2019-03-13 10:22:53 +01:00
parent 194dbeac50
commit 3b0d4f742f
8 changed files with 718 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

75
1130225163.cfdg Normal file
View File

@ -0,0 +1,75 @@
startshape START
background { hue 180 sat 0.1 b 0.9 }
rule START {
SCENE { hue 180 sat 0.8 b 0.8 }
}
rule SCENE {
FLOW { }
FLOW { flip -90 }
}
rule FLOW {
SQUARE { }
FLOW { x 1 s 0.994 r 3}
}
rule FLOW 0.001 {
SQUARE { }
CIRCLE { s 15 alpha -0.7 }
CIRCLE { s 3 x 17 alpha -0.7 }
FLOW { x 1 s 0.994 r 3}
}
rule FLOW 0.01 {
SQUARE { }
CIRCLE { x 10 s 15 alpha -0.9 }
CIRCLE { s 3 x -10 alpha -0.8 }
FLOW { x 1 s 0.994 r 3}
}
rule FLOW 0.0008 {
# CIRCLE { s 5 }
FLOWER { alpha -0.5 x 20 y 20}
FLOW { flip -3 }
}
rule FLOWER {
CIRCLE { s 9 2 r 75 x 0.5}
FLOWER { s 0.9 r 40 }
}
rule FLOW 0.01 {
FLOW { flip 2 }
}
rule FLOW 0.02 {
CIRCLE { s 5 4}
FLOW { flip 15 }
FLOW { r -45 s 0.4}
}
rule FLOW 0.01 {
SQUARE { }
BUBBLE { }
FLOW { x 1 s 0.994 r 3}
}
rule FLOW 0.01 {
SQUARE { }
FLOWER { y 15 alpha -0.7 }
FLOW { x 1 s 0.994 r 3}
}
rule BUBBLE {
CIRCLE { s 15 alpha -0.7 }
CIRCLE { s 3 x 17 alpha -0.7 }
BUBBLE { y 15 s 0.5 alpha -0.01 r 15}
}

32
1158352481.cfdg Normal file
View File

@ -0,0 +1,32 @@
startshape START
background {b -1}
rule START {GRAF{skew 6 9}GRAF{skew 1 1 r 81}}
rule GRAF {BB{}BB{flip 180}}
rule BB 60{AAA{} BB{z -.1 a -.01 s .99 y .3 hue 6}}
rule BB {BBB{flip 90} BB{}}
rule BB {BBB{} BB{}}
rule BB {BBB{flip 90}}
rule BB {BBB{}}
rule BB .3{DD{}}
rule BBB 100{AAA{} BBB{a -.01 s .997 r 2 y .3 hue 6}}
rule BBB 1{BBB{flip 90}}
rule DD 100{AAA{} DD{z 1 a .01 s 1.01 y .3 hue 6}}
rule DD {BB{}}
rule AAA 50{SQUARE{b 1 a -.9} SQUARE{a -.6 s .1 3} }
rule AAA 50{SQUARE{a -.9} SQUARE{b 1 a -.6 s .3 3} }
rule AAA 1.5{SQUARE{a -.8 s 4.5 1.2}}
rule AAA 1{SQUARE{a -.8 s 4.5 1.2}CCC{a 1}}
rule AAA .5{SQUARE{a -.8 s 4.5 1.2}CCC{a 1}CCC{a 1 flip 90}}
rule AAA 9{SQUARE[a -.75 s 2 1 r 45 b 0.5 sat 0.5 hue 220]}
rule AAA 9{SQUARE[a -.75 s 2 1 r 45 b 0.5 sat 0.5 hue 330]}
rule AAA .1{SQUARE{z -30 a -.93 b .6 s 30}}
rule AAA 12{}
rule AAA .03{SQUARE{z -30 a -.3 b .6 s 12} BB{}}
rule CCC 150{AAA{r 90} CCC{x 1 s .96}}
rule CCC 3{CCC{}CCC{r 90}}
rule CCC {CCC{}CCC{r -90}}

77
Flesh and Blood.cfdg Normal file
View File

@ -0,0 +1,77 @@
startshape START
#Variations remarquables : I, V, ZZTPD
CF::Background = [ hue 10 sat 0.1 b 1 ]
shape START
{
SCENE [ hue -10 sat 0.9 b 0.9 ]
}
shape SCENE
{
FLOW []
FLOW [flip -90]
}
shape FLOW
rule {
SQUARE []
FLOW [x 1 r 3 s 0.994]
}
rule 0.005 {
SQUARE []
BUBBLES [s 10]
FLOW [x 1 r 3 s 0.994]
}
rule 0.025 {
SQUARE []
CIRCLE [x -25..25 s 3..30 a -0.9]
FLOW [x 1 r 3 s 0.994]
}
rule 0.025 {
SQUARE []
RING [x 15..20 z -100 s 5]
FLOW [x 1 r 3 s 0.994]
}
rule 0.003 {
SQUARE []
FLOW [x 1 r 3 s 0.994]
FLOW [x 1 r 3 s 0.994 flip 0]
}
rule 0.01 {
SQUARE []
FLOW [x 1 r 3 s 0.994 flip 0]
}
rule 0.0007 {
SQUARE []
END [s 0.994]
}
shape RING
{
CIRCLE [a -0.65]
CIRCLE [hue 20 b 1 sat -1 s 0.9 a -0.25]
}
shape BUBBLES
rule {
CIRCLE [a -0.9]
BUBBLES [x -0.8..0.8 y -0.8..0.8]
}
rule 0.3 {
CIRCLE [a -0.9]
}
shape END
{
loop 20 [x 0.2 s 1.1 1.04]
CIRCLE []
}

169
city-reflection.cfdg Normal file
View File

@ -0,0 +1,169 @@
/*
city-reflection.cfdg
by AK, Jan 2009
city.cfdg with reflections
Variants: IOH, XCZ, ...
*/
startshape city
background { b -0.90 h 270 sat 0.5 }
/** city has horizontal "skyline" strips vanishing into distance **/
rule city {
skyline{y -20}
city { s -0.9 0.85 0.9 }
}
rule city 0.1{} // on average 10 skyline strips
rule skyline{ // each strip consists of two half-strips back-to-back
semiskyline{ x 9 }
semiskyline { x 3 flip 90 }
}
rule semiskyline 2 {
building_site{}
semiskyline { x 15 }
}
rule semiskyline 2 {
building_site{}
semiskyline { x 20 }
}
rule semiskyline{} // on average 5 building sites per semiskyline
/*************** building sites: some occupied, some vacant ***********/
rule building_site 2{
building{s 10 10 10} // building drawn in the plane z=10 with reflection drawn in the plane z=-10
G{s 50 5 b 0 sat 1 h 60}
haze {z 9.9 }
haze {z 10.1 }
}
rule building_site 1{
G{s 50 5 b 0 sat 1 h 60}
haze {z 9.9 }
}
/* Each building has a random number of +/- 20% rescaling
steps applied to it. */
rule building 3{building{ s 1 0.8}}
rule building 3{building {s 1 1.2}}
rule building 2{building{ s 0.8 1}}
rule building 2{building {s 1.2 1}}
/* There are three types of buildings, of height 1, 2 or 4 units.
Each has a matching reflection that is proportional
to the building. */
rule building{ B1{ z 1} R1{z -1} }
rule building{ B2{z 1} R2{z -1} }
rule building{ B3{z 1} R3{z -1} }
rule B1{BOX{}}
rule B2{B1{y 1}B1{}}
rule B3{B2{y 2}B2{}}
/* There are three different styles of reflection possible */
// Style 1: reflections on rough water
rule R1{RF{ s 1.2 -1.4 y -0.5 b 0.5 sat 0.3 h 180}}
rule R2{RF{ s 1.2 -2.8 y -0.5 b 0.7 sat 0.3 h 180}}
rule R3{RF{ s 1.2 -5.6 y -0.5 b 0.9 sat 0.3 h 180}}
/* vvv----------- unused code --------vvv
// Style 2: reflections on smooth water - not so good as different windows are lit
rule R1{B1{h 240 sat 0.5 b -0.5 s -1}}
rule R2{B2{h 240 sat 0.5 b -0.5 s -1}}
rule R3{B3{h 240 sat 0.5 b -0.5 s -1}}
// Style 3: tapered reflections on smooth water
rule R1{BOX{h 240 sat 0.5 b -0.5 s -1}}
rule R2{R1{ y -1 s 0.8 1} R1{ s 1.2 1} }
rule R3{R2{ y -2 s 0.64 1 } R2{ s 1.44 1}}
^^^----------- unused code -----------^^^ */
/* This is the element from which buildings are built. A box with windows. */
rule BOX{
SQUARE{ y 0.5 }
wa{ y 0.5 s 0.8 1 z 0.1}
}
/* get windows on BOX by progressive subdivision */
rule wa{ wb { s 1 0.5 y -0.25 } wb{ s 1 0.5 y 0.25 } }
rule wb{ wc{ s 1 0.5 y -0.25 } wc{ s 1 0.5 y 0.25 } }
rule wc{ wd{ s 0.5 1 x -0.25 } wd { s 0.5 1 x 0.25 }}
rule wd{ we{ s 0.5 1 x -0.25 } we { s 0.5 1 x 0.25 }}
/* but only some windows are lit */
rule we 2 {}
rule we{ win{}}
/* some alternative window subdivision pathways that give all or no lit windows on a floor */
rule wc 0.1{ wdx{ s 0.5 1 x -0.25 } wdx { s 0.5 1 x 0.25 }}
rule wc 0.1{}
rule wdx{ win{ s 0.5 1 x -0.25 } win { s 0.5 1 x 0.25 }}
/* possibly tweak window colour and brightness */
rule win 3{ win {b 0.2 }}
rule win 3{ win {b -0.2 }}
rule win { win {h 20 }}
/* a window */
rule win{
SQUARE { size .8 0.7 b .5 sat +0.2 }
SQUARE { s 0.1 0.8 b -1} // vertical divider
// SQUARE { s 0.8 0.1 b -1} // horizontal divider
}
/* Reflection on rough water.
The tear-drop shape comes from a shape
being scaled non-proportionally
while progressively shifted. */
rule RF{
SPARKLE{ s 2 0.1 x 1}
SPARKLE{ s 2 0.1 b 0.2}
RF[ y 1 s -0.9 0.96 y -1 b -0.02]
}
rule SPARKLE{ // shiny filler
CIRCLE{ s 1.5 0.5 a -0.98}
6 * {r 60} SPARK { s 0.15 x 0.5 a -0.8}
}
rule SPARK{TRIANGLE{}}
rule SPARK 5{SPARK{r 222}}
rule SPARK 2{SPARK{x 1}}
rule SPARKLE 5 {SPARKLE{r 223}}
rule SPARKLE 2{
SPARKLE{s 0.7 x 0.5}
SPARKLE{s 0.7 x -0.5}
}
rule SPARKLE 0.5{}
/* Ground - a generic blobby shape */
rule G{ CIRCLE{} }
rule G{ CIRCLE{}
G{ y -0.5 s 0.7 0.7 r 60}
G{ y -0.5 s 0.7 0.7 r -60} }
rule G{ G {r 10}}
rule G{G { flip 90}}
rule G 0.2{}
/* ------------ Ground level haze ------------*/
rule haze { haze { x .1 }}
rule haze { haze { x -.1 }}
rule haze {
hazecircle { }
haze { s 1 0.3 x .5 b .3}
haze { s 1 0.3 x -.5 b .3}
}
rule haze .5{}
rule hazecircle { hazecircle { r 10 }}
rule hazecircle { hazecircle { flip 90 }}
rule hazecircle {
CIRCLE { s 30 20 z 0.1 h 40 b 0.5 sat .2 a -0.98 }
}

53
navigation-map.cfdg Normal file
View File

@ -0,0 +1,53 @@
dot_size = 0.15
CF::Size = [s 80 x -8]
CF::Background = [b -0.9 h 230 sat 0.75]
startshape galaxy[b 1]
shape galaxy {
dot[s 10]
loop 9[] {
distance = 4..30
ring(distance)[]
planet_rotation = 1..360
trans[[r planet_rotation x distance]] {
CIRCLE[s 0.2..0.8]
trans [r -planet_rotation] {
marker[]
}
}
}
}
shape ring(distance) {
loop (360)[r 1..6]
dot[x distance]
}
shape marker {
loop 8[x 0.2 y 0.2] {
dot[]
} finally {
script[x 1 y 0.6]
loop 96[x 0.2] {
dot[]
}
}
}
shape script {
loop 4..20[x 1]
char[a -0.25]
}
shape char
rule { }
rule 4 { SQUARE[s 0.5 0.5] }
rule { SQUARE[s 0.5 0.25] }
rule { char[y 0.5] }
shape dot {
CIRCLE[s dot_size a 0.5]
loop 1..2[x rand::normal(0,1) rand::normal(0,1)]
SQUARE[s 1..2 a -0.998]
}

203
scanner.cfdg Normal file
View File

@ -0,0 +1,203 @@
startshape go
background { b -1.0 }
rule go {
crosshairs { h 30 b 0.75 sat 0.9 a 1}
sweeps {h 70 b 0.8 sat 0.8 a -0.7}
rings {h 110 b 0.25 sat 0.7 a 0.6}
artifacts {h 210 b 1 sat 1 a -0.5}
}
rule crosshairs {
2 * {r 45 a -0.5} {
2 * {r 22.5 a -0.75} {
3 * {r 0.3} crosshair {r -0.3}
}
}
}
rule crosshair {
SQUARE {s 0.01 20}
SQUARE {s 20 0.01}
}
rule sweeps { 7 * {r 51 s 0.75} {sweepo {} } }
rule sweepo 3 { sweepr1 {} }
rule sweepo 1 {}
rule sweepr1 { sweepr2 {r -63} }
rule sweepr1 { sweepr2 {} }
rule sweepr1 { sweepr2 {r 63} }
rule sweepr2 { sweepr3 {r -21} }
rule sweepr2 { sweepr3 {} }
rule sweepr2 { sweepr3 {r 21} }
rule sweepr3 { sweep {r -7} }
rule sweepr3 { sweep {} }
rule sweepr3 { sweep {r 7} }
rule sweep {
radialw {h 20 a -0.75}
curl {s 10.2 b 0.9 a -0.9}
}
rule radialw { radials {} }
rule radialw { radials {s 0.75 1} }
rule radialw { radials {s 0.5 1} }
rule radialw { radials {s 0.25 1} }
rule radials {
8 * {s 0.85 1} {
TRIANGLE {a -0.1 y -6.5 s 1 11.5}
}
}
rule curl {
3 * {s 0.97} { 3 * {s 0.99} curl1a {} }
}
rule curl {
3 * {s 0.97} { 3 * {s 0.99} curl2a {} }
}
rule curl {
3 * {s 0.97} { 3 * {s 0.99} curl3a {} }
}
rule curl {
3 * {s 0.97} { 3 * {s 0.99} curl4a {} }
}
rule curl {
3 * {s 0.97} { 3 * {s 0.99} curl5a {} }
}
rule curl {
3 * {s 0.97} { 3 * {s 0.99} curl6a {} }
}
path curl1a {
MOVETO {x 0.0 y -1.0}
ARCTO {x -0.6 y -0.8 r 1 p cw}
STROKE {width 0.25 p roundcap}
}
path curl2a {
MOVETO {x 0.0 y -1.0}
ARCTO {x -0.8 y -0.6 r 1 p cw}
STROKE {width 0.25 p roundcap}
}
path curl3a {
MOVETO {x 0.0 y -1.0}
ARCTO {x -1.0 y 0.0 r 1 p cw}
STROKE {width 0.25 p roundcap}
}
path curl4a {
MOVETO {x 0.0 y -1.0}
ARCTO {x -0.8 y 0.6 r 1 p cw}
STROKE {width 0.25 p roundcap}
}
path curl5a {
MOVETO {x 0.0 y -1.0}
ARCTO {x -0.6 y 0.8 r 1 p cw}
STROKE {width 0.25 p roundcap}
}
path curl6a {
MOVETO {x 0.0 y -1.0}
ARCTO {x 0.0 y 1.0 r 1 p cw}
STROKE {width 0.25 p roundcap}
}
rule rings {
10 * {s 0.75 b 0.1 a 0.1} ring {s 10}
}
rule ring {
5 * {s 0.995 a -0.25} cycle {}
5 * {s 1.005 a -0.25} cycle {}
}
path cycle {
MOVETO {x 0 y 1}
ARCTO {x 0 y -1 r 1 p cw}
ARCTO {x 0 y 1 r 1 p cw}
STROKE {width 0.005}
}
rule artifacts {
4 * {x 0.1} artifactx1 {}
}
rule artifactx1 {artifactx2 {x -3}}
rule artifactx1 {artifactx2 {}}
rule artifactx1 {artifactx2 {x 3}}
rule artifactx2 {artifactx3 {x -1}}
rule artifactx2 {artifactx3 {}}
rule artifactx2 {artifactx3 {x 1}}
rule artifactx3 {artifactx4 {x -0.6}}
rule artifactx3 {artifactx4 {}}
rule artifactx3 {artifactx4 {x 0.6}}
rule artifactx4 {artifacty1 {x -0.2}}
rule artifactx4 {artifacty1 {}}
rule artifactx4 {artifacty1 {x 0.2}}
rule artifacty1 {artifacty2 {y -3}}
rule artifacty1 {artifacty2 {}}
rule artifacty1 {artifacty2 {y 3}}
rule artifacty2 {artifacty3 {y -1}}
rule artifacty2 {artifacty3 {}}
rule artifacty2 {artifacty3 {y 1}}
rule artifacty3 {artifacty4 {y -0.6}}
rule artifacty3 {artifacty4 {}}
rule artifacty3 {artifacty4 {y 0.6}}
rule artifacty4 {artifact {y -0.2}}
rule artifacty4 {artifact {}}
rule artifacty4 {artifact {y 0.2}}
rule artifact {
12 * {s 0.9 a 0.1} CIRCLE {s 0.25}
caption {}
}
rule caption {
bracket {}
label1 {x -4.8 y -0.85 b -0.4 a -0.4 sat -0.2}
label2 {x -1.1 y -1.15 b -0.4 a -0.4 sat -0.2 r 180}
}
path bracket {
MOVETO {x 0 y 0}
LINETO {x -1 y -1}
LINETO {x -5 y -1}
STROKE {width 0.05}
}
rule label1 {
24 * {x 0.1} symbolc {s 0.2}
}
rule label2 {
12 * {x 0.1} symbolc {s 0.2}
}
rule symbolc {symbolr {}}
rule symbolc {symbolr {h 90}}
rule symbolc {symbolr {h 120}}
//rule symbolc {symbolr {h 180}}
//rule symbolc {symbolr {h 240}}
//rule symbolc {symbolr {h 270}}
rule symbolc {}
rule symbolr {symbol{}}
rule symbolr {symbol{r 90}}
rule symbolr {symbol{r 120}}
rule symbolr {symbol{r 180}}
rule symbolr {symbol{r 240}}
rule symbolr {symbol{r 270}}
rule symbol { TRIANGLE {} }
rule symbol { SQUARE {} }
rule symbol { CIRCLE {} }

56
tree-2.cfdg Normal file
View File

@ -0,0 +1,56 @@
startshape fu [b 1]
CF::Background = [b -1]
shape fu {
loop 2 [r 180] foo [r 33 hue 120 sat 1 b -0.5]
}
shape foo
rule 90 {
dr []
foo [y 0.1 r 0.3 s 0.999 b -0.0003]
}
rule 0.2 {
dr []
foo [y 0.1 r 0.3 s 0.999]
bar []
}
rule 0.2 {
dr []
foo [y 0.1 r 0.3 s 0.999]
sna []
}
shape bar
rule 90 {
dr []
bar [y 0.1 r 1 s 0.996 b 0.005]
}
rule 0.1 {
dr []
end []
}
shape sna
rule 90 {
dr []
sna [y 0.1 r -1 s 0.996 b 0.005]
}
rule 0.2 {
dr []
end []
}
shape end {
bar []
sna []
}
shape dr {
CIRCLE [y 0.5 s 1.5 b -0.5 a -0.9]
CIRCLE []
}

53
waves-3.cfdg Normal file
View File

@ -0,0 +1,53 @@
startshape GRID (1000,1000)[] //( 640, 640 ) []
CF::Time = [time 0 1]
CF::Background = [ b -1 ]
CF::MinimumSize = 0.0001
sine(t,amp,freq,phase) = amp*sin( 360 * (freq*t + phase) )
dist ( n, o ) = abs ( n - o )
inv2 ( n ) = 1/n^2
para ( n, o, p ) = n^2*o+p
st0 = sine ( ftime(), 1, 3, 0.2 )
st1 = sine ( ftime(), 1, 3, 0.5 )
st2 = sine ( ftime(), 1, 2, 0.9 )
shape GRID ( natural n, natural o )
{
loop i=n []
{
si0 = sine ( i/n, 1, 1, 0 )
si1 = sine ( i/n, 1, 2, 0.2 )
si2 = sine ( i/n, 1, 3, 0.7 )
s0 = sine ( (1/n)*i, o/3*si0, 3, ftime() )+st0
s1 = sine ( (1/n)*i, o/3*si1, 2, ftime() )+st1
s2 = sine ( (1/n)*i, o/3*si2, 1, ftime() )+st2
X = i-(n/2)
loop j=o []
{
Y = j-(o/2)
BC = 0.02
BN = 2/3
BM = 1.4
B0 = BN/para ( BC, dist ( Y, s0 )^2, BM )
B1 = BN/para ( BC, dist ( Y, s1 )^2, BM )
B2 = BN/para ( BC, dist ( Y, s2 )^2, BM )
B = B0+B1+B2
S = 1.2-(B0+B1+B2)
H = st0*st1*st2*si0+190
SQUARE [ x X y Y b B sat S hue H]
}
}
}